100 ' The Weather Channel's Wind Chill Chart
110 ' Copyright J.T.Norman 1982
120 ' The Weather Channel
130 ' 2840 Mount Wilkinson Parkway
140 ' Atlanta, Georgia 30339
150 '
160 ' A Cable programming service of Landmark Communications, Inc.
170 '
180 ' Tested on Microsoft Basic on IBM Personal Computer
190 ' Should function on Apple, and TRS-80 with minimum change
200 '
210 LPRINT "__________________________________________________________________"
220 LPRINT "                        Wind Chill Chart  "
230 U$ = "#####"
240 LPRINT "                   Actual Thermometer Reading (F)  "
250 U1$ = "##."
260 LPRINT "Est. Wind  "
270 LPRINT " Speed   50   40   30   20   10   0  -10  -20  -30  -40  -50  -60"
280 LPRINT " in MPH              Equivalent Temperature (F)
290 LPRINT "__________________________________________________________________"
300 LPRINT "  Calm";
310 FOR MH = 0  TO 40  STEP 5
320 IF MH < 4 THEN MH = 4:GOTO 340
330 LPRINT "    ";USING U1$;MH;
340 FOR TF = 50  TO -60  STEP -10
350 TC  = ((5*TF)-160)/9      'Degrees F to Degrees C
360 MS = (.447 * MH)        'meters per second
370 WI = (10.45 + (10* (SQR(MS)))-MS)*(33-TC)  'Calculation
380 WT = (-.04544 * WI) + 33 ' wind temp centigrade
390 FT = (160+ (9*WT))/5     'degrees f
400 FT = INT (FT + .5)       'rounding
410 LPRINT USING U$;FT;
420 NEXT TF
430 LPRINT
440 IF MH= 4 THEN MH = 0
450 NEXT MH
460 LPRINT "__________________________________________________________________"
470 END
0 IF MH= 4 THEN MH = 0
450 N